rollout SmoothTool "SmoothTool ver1.11" width:280 height:210
(
	--layout--
	GroupBox grp_Setting "Setting" pos:[10,10] width:260 height:149
		dropdownList ddl_SearchModifier "[Search Modifier]" pos:[20,30] width:100 height:41 items:#("TurboSmooth", "MeshSmooth")
		radiobuttons rdo_SearchObject "[Search Object]" pos:[20,80] width:60 height:62 labels:#("All", "Select", "Filter:") columns:1
		edittext edt_SearchObjFilter "" pos:[70,125] width:60 height:18
	
		label lbl_Iterations "Iterations:" pos:[172,30] width:55 height:20
		spinner spn_Iterations "" pos:[225,30] width:35 height:16 range:[0,9,1] type:#integer
		checkbox chk_RenderIters "Render Iters:" pos:[140,55] width:85 height:20
		spinner spn_RenderIters "" pos:[225,55] width:35 height:16 range:[0,9,0] type:#integer
		checkbox chk_IsolineDisplay "Isoline Display" pos:[140,80] width:95 height:20
		checkbutton chk_InstanceModifier "InstanceModifier" pos:[150,110] width:100 height:30
	
	button btn_Select "Select" pos:[30,165] width:100 height:35
	button btn_Apply "Apply" pos:[150,165] width:100 height:35
	
	--fn--
	fn searchObj =
	(
		global modType
		case ddl_SearchModifier.text of
		(
			"TurboSmooth": modType = TurboSmooth
			"MeshSmooth": modType = MeshSmooth
		)
		
		if rdo_SearchObject.state == 1 then
		(
			local searchAll = #()
			for o in objects do (if o.modifiers[modType] != undefined then (append searchAll o))
			clearSelection()
			select searchAll
		)
		if rdo_SearchObject.state == 2 then
		(
			local searchSelect = #()
			for s in selection do (if s.modifiers[modType] != undefined then (append searchSelect s))
			clearSelection()
			select searchSelect
		)
		if rdo_SearchObject.state == 3 then
		(
			local searchFilterObj = #()
			local searchFilterMod = #()
			for o in objects do (if findString o.name edt_SearchObjFilter.text != undefined then (append searchFilterObj o))
			clearSelection()
			select searchFilterObj
			for s in selection do (if s.modifiers[modType] != undefined then (append searchFilterMod s))
			clearSelection()
			select searchFilterMod
		)
	)
	
	--code--
	on btn_Select pressed do
	(
		searchObj()
	)
	on btn_Apply pressed do
	(
		searchObj()
		
		if chk_InstanceModifier.state == true then
		(
			for s in selection do
			(
				for m in s.modifiers do
				(
					if classOf m == modType do (deleteModifier s m)
				)
			)
			addModifier $ (modType iterations:spn_Iterations.value useRenderIterations:chk_RenderIters.state renderIterations:spn_RenderIters.value isolineDisplay:chk_IsolineDisplay.state)
		)
			
		if chk_InstanceModifier.state == false then
		(
			for s in selection do
			(
				s.modifiers[modType].iterations = spn_Iterations.value
				s.modifiers[modType].useRenderIterations = chk_RenderIters.state
				s.modifiers[modType].renderIterations = spn_RenderIters.value
				s.modifiers[modType].isolineDisplay = chk_IsolineDisplay.state
			)
		)
	)	
)
createDialog SmoothTool